Amiga Format CD 19/Amiga Format CD19 (1997-10-02)(Future Publishing)(GB)(Track 1 of 5)[!][issue 1997-11].iso/-seriously_amiga-/shareware/workbench/tragicwb/install_tragicwb

Text File | 1997-08-26 | 5KB | 180 lines

(
    ;Warn about buggy versions of Installer
    (if (< @installer-version 43)
    (message "Since you have an old version of Installer, this script "
        "may not work correctly. You are advised to abort now and update "
        "your copy of Installer before proceeding." (all))
    )

    (if (= @user-level 0)
    (fail "\n\nThis script does not run in Novice mode.")
    )

    (set #inst-op
    (askchoice
        (prompt "Select the operation you wish to carry out:")
        (help @askchoice-help)
        (choices "pInstall TragicWB" "Update TragicWB" "Uninstall TragicWB")
    )
    )

    (set #dest
    (askdir
        (prompt
        ("Select the directory %s:"
            (select (= #inst-op 0) "TragicWB was installed in" "to install TragicWB in")
        )
        )
        (help @askdir-help)
        (default "C:")
    )
    )

    (set @default-dest #dest)
    (set #dest-file (tackon #dest "TragicWB"))

    (set #inst-guide
    (or
        (= @user-level 0)
        (askbool
        (prompt
            ("Do you want to %s the guide to TragicWB?"
            (select #inst-op "install" "update" "delete")
            )
        )
        (help "Answer Yes if you want the guide to be easily "
            "accessible. Answer No if you don't mind hunting "
            "for it when you need it...")
        )
    )
    )

    (if #inst-guide
    (set #guide-dest
        (askdir
        (prompt
            ("Select the directory %s:"
            (select (= #inst-op 0) "the guide was installed in" "to install the guide in")
            )
        )
        (help @askdir-help)
        (default "HELP:english/")
        )
    )
    )

    (if (= #inst-op 2)
    (
        (delete #dest-file)
        (if #inst-guide
        (delete (tackon #guide-dest "TragicWB.guide"))
        )
        (startup @app-name "" (prompt "") (help ""))
        (exit "\n\nUninstallation complete. Aw, didn't you like my program?" (quiet))
    )
    )

    (if (= #inst-op 0)
    (
        (set #startup
        (askbool
            (prompt "Do you want TragicWB to start when you boot your Amiga?")
            (help "If you answer Yes, TragicWB will be added to your "
              "user-startup file, so it will start automatically "
              "when you switch on or reboot your Amiga. If you "
              "answer No, you will have to start TragicWB "
              "from a CLI, which isn't very convenient and "
              "may not work at all.")
        )
        )

        (set #installpal
        (askbool
            (prompt "Do you want to use the Magic Workbench palette?")
            (help "If you answer Yes, your palette preferences will "
              "be set to the Magic Workbench  colour scheme. If you answer "
              "No, then your palette will not be changed, and "
              "old-style Magic Workbench icons will still have the wrong "
              "colours.")
        )
        )

        (set #depth "")

        (set #depth-opt
        (askchoice
            (prompt "When should TragicWB obtain pens for the standard "
            "NewIcons colours?")
            (help "If you don't use NewIcons or don't want to change "
            "the way NewIcons dynamically allocates pens, answer "
            "\"Never\". Otherwise choose how the minimum number "
            "of colours on the Workbench screen for TragicWB "
            "to allocate NewIcons pens. I'd suggest choosing "
            "32 or 64 colours, as preferences plus MagicWB "
            "plus NewIcons colours gives a total of 22 pens.")
            (choices
            "pNever"
            "When WB has 16 or more colours"
            "When WB has 32 or more colours"
            "When WB has 64 or more colours"
            "When WB has 128 or more colours"
            "When WB has 256 or more colours")
        )
        )
        (if (> #depth-opt 0)
        (set #depth (" NEWICONSDEPTH=%ld" (+ #depth-opt 3)))
        )

        (set #startnow
        (askbool
            (prompt "Do you want to start TragicWB now?")
            (help "If you answer Yes, TragicWB will be started as "
              "soon as it has been installed. If you answer "
              "No, it will not start until you reboot or run "
              "it from a CLI.")
        )
        )
    )
    )

    (complete 20)

    (copyfiles (source "TragicWB") (dest #dest) (prompt "") (help ""))
    (if #inst-guide
    (copyfiles (source "TragicWB.guide") (dest #guide-dest) (infos))
    )

    (if (= #inst-op 1)
    (exit "\n\nUpdate complete." (quiet))
    )

    (complete 40)

    (if #startup
    (startup @app-name
        (command (cat #dest-file #depth))
        (prompt "") (help "")
    )
    )

    (if #installpal
    (
        (copyfiles (source "MWB-palette.pre") (dest "envarc:sys") (newname "palette.prefs") (prompt "") (help ""))

        (complete 60)

        (if #startnow
        (copyfiles (source "MWB-palette.pre") (dest "env:sys") (newname "palette.prefs") (prompt "") (help ""))
        )
    )
    )

    (complete 80)

    (if #startnow
    (run (cat #dest-file #depth) (prompt "") (help ""))
    )

    (exit "\n\nInstallation complete." (quiet))
)